Refactoring

ray_tracing_motionblur/shaders/frag_shader.frag

@@ -0,0 +1,99 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 450
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_EXT_nonuniform_qualifier : enable
+#extension GL_GOOGLE_include_directive : enable
+#extension GL_EXT_scalar_block_layout : enable
+
+#extension GL_EXT_shader_explicit_arithmetic_types_int64 : require
+#extension GL_EXT_buffer_reference2 : require
+
+#include "wavefront.glsl"
+
+
+layout(push_constant) uniform _PushConstantRaster
+{
+  PushConstantRaster pcRaster;
+};
+
+// clang-format off
+// Incoming 
+layout(location = 1) in vec3 i_worldPos;
+layout(location = 2) in vec3 i_worldNrm;
+layout(location = 3) in vec3 i_viewDir;
+layout(location = 4) in vec2 i_texCoord;
+// Outgoing
+layout(location = 0) out vec4 o_color;
+
+layout(buffer_reference, scalar) buffer Vertices {Vertex v[]; }; // Positions of an object
+layout(buffer_reference, scalar) buffer Indices {uint i[]; }; // Triangle indices
+layout(buffer_reference, scalar) buffer Materials {WaveFrontMaterial m[]; }; // Array of all materials on an object
+layout(buffer_reference, scalar) buffer MatIndices {int i[]; }; // Material ID for each triangle
+
+layout(binding = eObjDescs, scalar) buffer ObjDesc_ { ObjDesc i[]; } objDesc;
+layout(binding = eTextures) uniform sampler2D[] textureSamplers;
+// clang-format on
+
+
+void main()
+{
+  // Material of the object
+  ObjDesc    objResource = objDesc.i[pcRaster.objIndex];
+  MatIndices matIndices  = MatIndices(objResource.materialIndexAddress);
+  Materials  materials   = Materials(objResource.materialAddress);
+
+  int               matIndex = matIndices.i[gl_PrimitiveID];
+  WaveFrontMaterial mat      = materials.m[matIndex];
+
+  vec3 N = normalize(i_worldNrm);
+
+  // Vector toward light
+  vec3  L;
+  float lightIntensity = pcRaster.lightIntensity;
+  if(pcRaster.lightType == 0)
+  {
+    vec3  lDir     = pcRaster.lightPosition - i_worldPos;
+    float d        = length(lDir);
+    lightIntensity = pcRaster.lightIntensity / (d * d);
+    L              = normalize(lDir);
+  }
+  else
+  {
+    L = normalize(pcRaster.lightPosition);
+  }
+
+
+  // Diffuse
+  vec3 diffuse = computeDiffuse(mat, L, N);
+  if(mat.textureId >= 0)
+  {
+    int  txtOffset  = objDesc.i[pcRaster.objIndex].txtOffset;
+    uint txtId      = txtOffset + mat.textureId;
+    vec3 diffuseTxt = texture(textureSamplers[nonuniformEXT(txtId)], i_texCoord).xyz;
+    diffuse *= diffuseTxt;
+  }
+
+  // Specular
+  vec3 specular = computeSpecular(mat, i_viewDir, L, N);
+
+  // Result
+  o_color = vec4(lightIntensity * (diffuse + specular), 1);
+}

ray_tracing_motionblur/shaders/host_device.h

@@ -0,0 +1,118 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+
+#ifndef COMMON_HOST_DEVICE
+#define COMMON_HOST_DEVICE
+
+#ifdef __cplusplus
+#include "nvmath/nvmath.h"
+// GLSL Type
+using vec2 = nvmath::vec2f;
+using vec3 = nvmath::vec3f;
+using vec4 = nvmath::vec4f;
+using mat4 = nvmath::mat4f;
+using uint = unsigned int;
+#endif
+
+// clang-format off
+#ifdef __cplusplus // Descriptor binding helper for C++ and GLSL
+ #define START_BINDING(a) enum a {
+ #define END_BINDING() }
+#else
+ #define START_BINDING(a)  const uint
+ #define END_BINDING() 
+#endif
+
+START_BINDING(SceneBindings)
+  eGlobals  = 0,  // Global uniform containing camera matrices
+  eObjDescs = 1,  // Access to the object descriptions
+  eTextures = 2   // Access to textures
+END_BINDING();
+
+START_BINDING(RtxBindings)
+  eTlas     = 0,  // Top-level acceleration structure
+  eOutImage = 1   // Ray tracer output image
+END_BINDING();
+// clang-format on
+
+
+// Information of a obj model when referenced in a shader
+struct ObjDesc
+{
+  int      txtOffset;             // Texture index offset in the array of textures
+  uint64_t vertexAddress;         // Address of the Vertex buffer
+  uint64_t indexAddress;          // Address of the index buffer
+  uint64_t materialAddress;       // Address of the material buffer
+  uint64_t materialIndexAddress;  // Address of the triangle material index buffer
+};
+
+// Uniform buffer set at each frame
+struct GlobalUniforms
+{
+  mat4 viewProj;     // Camera view * projection
+  mat4 viewInverse;  // Camera inverse view matrix
+  mat4 projInverse;  // Camera inverse projection matrix
+};
+
+// Push constant structure for the raster
+struct PushConstantRaster
+{
+  mat4  modelMatrix;  // matrix of the instance
+  vec3  lightPosition;
+  uint  objIndex;
+  float lightIntensity;
+  int   lightType;
+};
+
+
+// Push constant structure for the ray tracer
+struct PushConstantRay
+{
+  vec4  clearColor;
+  vec3  lightPosition;
+  float lightIntensity;
+  int   lightType;
+  int   frame;
+};
+
+struct Vertex  // See ObjLoader, copy of VertexObj, could be compressed for device
+{
+  vec3 pos;
+  vec3 nrm;
+  vec3 color;
+  vec2 texCoord;
+};
+
+struct WaveFrontMaterial  // See ObjLoader, copy of MaterialObj, could be compressed for device
+{
+  vec3  ambient;
+  vec3  diffuse;
+  vec3  specular;
+  vec3  transmittance;
+  vec3  emission;
+  float shininess;
+  float ior;       // index of refraction
+  float dissolve;  // 1 == opaque; 0 == fully transparent
+  int   illum;     // illumination model (see http://www.fileformat.info/format/material/)
+  int   textureId;
+};
+
+
+#endif

ray_tracing_motionblur/shaders/passthrough.vert

@@ -0,0 +1,34 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 450
+layout(location = 0) out vec2 outUV;
+
+
+out gl_PerVertex
+{
+  vec4 gl_Position;
+};
+
+
+void main()
+{
+  outUV       = vec2((gl_VertexIndex << 1) & 2, gl_VertexIndex & 2);
+  gl_Position = vec4(outUV * 2.0f - 1.0f, 1.0f, 1.0f);
+}

ray_tracing_motionblur/shaders/post.frag

@@ -0,0 +1,37 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 450
+layout(location = 0) in vec2 outUV;
+layout(location = 0) out vec4 fragColor;
+
+layout(set = 0, binding = 0) uniform sampler2D noisyTxt;
+
+layout(push_constant) uniform shaderInformation
+{
+  float aspectRatio;
+}
+pushc;
+
+void main()
+{
+  vec2  uv    = outUV;
+  float gamma = 1. / 2.2;
+  fragColor   = pow(texture(noisyTxt, uv).rgba, vec4(gamma));
+}

ray_tracing_motionblur/shaders/random.glsl

@@ -0,0 +1,53 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+// Generate a random unsigned int from two unsigned int values, using 16 pairs
+// of rounds of the Tiny Encryption Algorithm. See Zafar, Olano, and Curtis,
+// "GPU Random Numbers via the Tiny Encryption Algorithm"
+uint tea(uint val0, uint val1)
+{
+  uint v0 = val0;
+  uint v1 = val1;
+  uint s0 = 0;
+
+  for(uint n = 0; n < 16; n++)
+  {
+    s0 += 0x9e3779b9;
+    v0 += ((v1 << 4) + 0xa341316c) ^ (v1 + s0) ^ ((v1 >> 5) + 0xc8013ea4);
+    v1 += ((v0 << 4) + 0xad90777d) ^ (v0 + s0) ^ ((v0 >> 5) + 0x7e95761e);
+  }
+
+  return v0;
+}
+
+// Generate a random unsigned int in [0, 2^24) given the previous RNG state
+// using the Numerical Recipes linear congruential generator
+uint lcg(inout uint prev)
+{
+  uint LCG_A = 1664525u;
+  uint LCG_C = 1013904223u;
+  prev       = (LCG_A * prev + LCG_C);
+  return prev & 0x00FFFFFF;
+}
+
+// Generate a random float in [0, 1) given the previous RNG state
+float rnd(inout uint prev)
+{
+  return (float(lcg(prev)) / float(0x01000000));
+}

ray_tracing_motionblur/shaders/raycommon.glsl

@@ -0,0 +1,23 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+struct hitPayload
+{
+  vec3 hitValue;
+};

ray_tracing_motionblur/shaders/raytrace.rchit

@@ -0,0 +1,145 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 460
+#extension GL_EXT_ray_tracing : require
+#extension GL_EXT_nonuniform_qualifier : enable
+#extension GL_EXT_scalar_block_layout : enable
+#extension GL_GOOGLE_include_directive : enable
+
+#extension GL_EXT_shader_explicit_arithmetic_types_int64 : require
+#extension GL_EXT_buffer_reference2 : require
+
+#include "raycommon.glsl"
+#include "wavefront.glsl"
+
+hitAttributeEXT vec2 attribs;
+
+// clang-format off
+layout(location = 0) rayPayloadInEXT hitPayload prd;
+layout(location = 1) rayPayloadEXT bool isShadowed;
+
+layout(buffer_reference, scalar) buffer Vertices {Vertex v[]; }; // Positions of an object
+layout(buffer_reference, scalar) buffer Indices {ivec3 i[]; }; // Triangle indices
+layout(buffer_reference, scalar) buffer Materials {WaveFrontMaterial m[]; }; // Array of all materials on an object
+layout(buffer_reference, scalar) buffer MatIndices {int i[]; }; // Material ID for each triangle
+layout(set = 0, binding = eTlas) uniform accelerationStructureEXT topLevelAS;
+layout(set = 1, binding = eObjDescs, scalar) buffer ObjDesc_ { ObjDesc i[]; } objDesc;
+layout(set = 1, binding = eTextures) uniform sampler2D textureSamplers[];
+
+layout(push_constant) uniform _PushConstantRay { PushConstantRay pcRay; };
+// clang-format on
+
+
+void main()
+{
+  // Object data
+  ObjDesc    objResource = objDesc.i[gl_InstanceCustomIndexEXT];
+  MatIndices matIndices  = MatIndices(objResource.materialIndexAddress);
+  Materials  materials   = Materials(objResource.materialAddress);
+  Indices    indices     = Indices(objResource.indexAddress);
+  Vertices   vertices    = Vertices(objResource.vertexAddress);
+
+  // Indices of the triangle
+  ivec3 ind = indices.i[gl_PrimitiveID];
+
+  // Vertex of the triangle
+  Vertex v0 = vertices.v[ind.x];
+  Vertex v1 = vertices.v[ind.y];
+  Vertex v2 = vertices.v[ind.z];
+
+  const vec3 barycentrics = vec3(1.0 - attribs.x - attribs.y, attribs.x, attribs.y);
+
+  // Computing the coordinates of the hit position
+  const vec3 pos      = v0.pos * barycentrics.x + v1.pos * barycentrics.y + v2.pos * barycentrics.z;
+  const vec3 worldPos = vec3(gl_ObjectToWorldEXT * vec4(pos, 1.0));  // Transforming the position to world space
+
+  // Computing the normal at hit position
+  const vec3 nrm      = v0.nrm * barycentrics.x + v1.nrm * barycentrics.y + v2.nrm * barycentrics.z;
+  const vec3 worldNrm = normalize(vec3(nrm * gl_WorldToObjectEXT));  // Transforming the normal to world space
+
+  // Vector toward the light
+  vec3  L;
+  float lightIntensity = pcRay.lightIntensity;
+  float lightDistance  = 100000.0;
+  // Point light
+  if(pcRay.lightType == 0)
+  {
+    vec3 lDir      = pcRay.lightPosition - worldPos;
+    lightDistance  = length(lDir);
+    lightIntensity = pcRay.lightIntensity / (lightDistance * lightDistance);
+    L              = normalize(lDir);
+  }
+  else  // Directional light
+  {
+    L = normalize(pcRay.lightPosition);
+  }
+
+  // Material of the object
+  int               matIdx = matIndices.i[gl_PrimitiveID];
+  WaveFrontMaterial mat    = materials.m[matIdx];
+
+
+  // Diffuse
+  vec3 diffuse = computeDiffuse(mat, L, worldNrm);
+  if(mat.textureId >= 0)
+  {
+    uint txtId    = mat.textureId + objDesc.i[gl_InstanceCustomIndexEXT].txtOffset;
+    vec2 texCoord = v0.texCoord * barycentrics.x + v1.texCoord * barycentrics.y + v2.texCoord * barycentrics.z;
+    diffuse *= texture(textureSamplers[nonuniformEXT(txtId)], texCoord).xyz;
+  }
+
+  vec3  specular    = vec3(0);
+  float attenuation = 1;
+
+  // Tracing shadow ray only if the light is visible from the surface
+  if(dot(worldNrm, L) > 0)
+  {
+    float tMin   = 0.001;
+    float tMax   = lightDistance;
+    vec3  origin = gl_WorldRayOriginEXT + gl_WorldRayDirectionEXT * gl_HitTEXT;
+    vec3  rayDir = L;
+    uint  flags  = gl_RayFlagsTerminateOnFirstHitEXT | gl_RayFlagsOpaqueEXT | gl_RayFlagsSkipClosestHitShaderEXT;
+    isShadowed   = true;
+    traceRayEXT(topLevelAS,  // acceleration structure
+                flags,       // rayFlags
+                0xFF,        // cullMask
+                0,           // sbtRecordOffset
+                0,           // sbtRecordStride
+                1,           // missIndex
+                origin,      // ray origin
+                tMin,        // ray min range
+                rayDir,      // ray direction
+                tMax,        // ray max range
+                1            // payload (location = 1)
+    );
+
+    if(isShadowed)
+    {
+      attenuation = 0.3;
+    }
+    else
+    {
+      // Specular
+      specular = computeSpecular(mat, gl_WorldRayDirectionEXT, L, worldNrm);
+    }
+  }
+
+  prd.hitValue = vec3(lightIntensity * attenuation * (diffuse + specular));
+}

ray_tracing_motionblur/shaders/raytrace.rgen

@@ -0,0 +1,101 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 460
+#extension GL_EXT_ray_tracing : require
+#extension GL_GOOGLE_include_directive : enable
+#extension GL_EXT_shader_explicit_arithmetic_types_int64 : require
+#extension GL_NV_ray_tracing_motion_blur : require
+
+#include "raycommon.glsl"
+#include "host_device.h"
+#include "random.glsl"
+
+// clang-format off
+layout(location = 0) rayPayloadEXT hitPayload prd;
+
+layout(set = 0, binding = eTlas) uniform accelerationStructureEXT topLevelAS;
+layout(set = 0, binding = eOutImage, rgba32f) uniform image2D image;
+layout(set = 1, binding = eGlobals) uniform _GlobalUniforms { GlobalUniforms uni; };
+layout(push_constant) uniform _PushConstantRay { PushConstantRay pcRay; };
+// clang-format on
+
+const int NBSAMPLES = 10;
+
+void main()
+{
+  // Initialize the random number
+  uint seed = tea(gl_LaunchIDEXT.y * gl_LaunchSizeEXT.x + gl_LaunchIDEXT.x, pcRay.frame);
+
+  vec3 hitValues = vec3(0);
+
+  for(int smpl = 0; smpl < NBSAMPLES; smpl++)
+  {
+
+    float r1 = rnd(seed);
+    float r2 = rnd(seed);
+    // Subpixel jitter: send the ray through a different position inside the pixel
+    // each time, to provide antialiasing.
+    vec2 subpixel_jitter = pcRay.frame == 0 ? vec2(0.5f, 0.5f) : vec2(r1, r2);
+
+    const vec2 pixelCenter = vec2(gl_LaunchIDEXT.xy) + subpixel_jitter;
+    const vec2 inUV        = pixelCenter / vec2(gl_LaunchSizeEXT.xy);
+    vec2       d           = inUV * 2.0 - 1.0;
+
+    vec4 origin    = uni.viewInverse * vec4(0, 0, 0, 1);
+    vec4 target    = uni.projInverse * vec4(d.x, d.y, 1, 1);
+    vec4 direction = uni.viewInverse * vec4(normalize(target.xyz), 0);
+
+    uint  rayFlags = gl_RayFlagsOpaqueEXT;
+    float tMin     = 0.001;
+    float tMax     = 10000.0;
+    float time     = rnd(seed);
+    // float time     = float(smpl)/float(NBSAMPLES); // stuttered motion
+    prd.hitValue = vec3(0, 0, 0);
+
+    traceRayMotionNV(topLevelAS,     // acceleration structure
+                     rayFlags,       // rayFlags
+                     0xFF,           // cullMask
+                     0,              // sbtRecordOffset
+                     0,              // sbtRecordStride
+                     0,              // missIndex
+                     origin.xyz,     // ray origin
+                     tMin,           // ray min range
+                     direction.xyz,  // ray direction
+                     tMax,           // ray max range
+                     time,           // time
+                     0               // payload (location = 0)
+    );
+    hitValues += prd.hitValue;
+  }
+  prd.hitValue = hitValues / NBSAMPLES;
+
+  // Do accumulation over time
+  if(pcRay.frame > 0)
+  {
+    float a         = 1.0f / float(pcRay.frame + 1);
+    vec3  old_color = imageLoad(image, ivec2(gl_LaunchIDEXT.xy)).xyz;
+    imageStore(image, ivec2(gl_LaunchIDEXT.xy), vec4(mix(old_color, prd.hitValue, a), 1.f));
+  }
+  else
+  {
+    // First frame, replace the value in the buffer
+    imageStore(image, ivec2(gl_LaunchIDEXT.xy), vec4(prd.hitValue, 1.f));
+  }
+}

ray_tracing_motionblur/shaders/raytrace.rmiss

@@ -0,0 +1,38 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 460
+#extension GL_EXT_ray_tracing : require
+#extension GL_GOOGLE_include_directive : enable
+#extension GL_EXT_shader_explicit_arithmetic_types_int64 : require
+
+#include "raycommon.glsl"
+#include "wavefront.glsl"
+
+layout(location = 0) rayPayloadInEXT hitPayload prd;
+
+layout(push_constant) uniform _PushConstantRay
+{
+  PushConstantRay pcRay;
+};
+
+void main()
+{
+  prd.hitValue = pcRay.clearColor.xyz * 0.8;
+}

ray_tracing_motionblur/shaders/raytraceShadow.rmiss

@@ -0,0 +1,28 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 460
+#extension GL_EXT_ray_tracing : require
+
+layout(location = 1) rayPayloadInEXT bool isShadowed;
+
+void main()
+{
+  isShadowed = false;
+}

ray_tracing_motionblur/shaders/vert_shader.vert

@@ -0,0 +1,66 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#version 450
+#extension GL_ARB_separate_shader_objects : enable
+#extension GL_EXT_scalar_block_layout : enable
+#extension GL_GOOGLE_include_directive : enable
+
+#extension GL_EXT_shader_explicit_arithmetic_types_int64 : require
+
+#include "wavefront.glsl"
+
+layout(binding = 0) uniform _GlobalUniforms
+{
+  GlobalUniforms uni;
+};
+
+layout(push_constant) uniform _PushConstantRaster
+{
+  PushConstantRaster pcRaster;
+};
+
+layout(location = 0) in vec3 i_position;
+layout(location = 1) in vec3 i_normal;
+layout(location = 2) in vec3 i_color;
+layout(location = 3) in vec2 i_texCoord;
+
+
+layout(location = 1) out vec3 o_worldPos;
+layout(location = 2) out vec3 o_worldNrm;
+layout(location = 3) out vec3 o_viewDir;
+layout(location = 4) out vec2 o_texCoord;
+
+out gl_PerVertex
+{
+  vec4 gl_Position;
+};
+
+
+void main()
+{
+  vec3 origin = vec3(uni.viewInverse * vec4(0, 0, 0, 1));
+
+  o_worldPos = vec3(pcRaster.modelMatrix * vec4(i_position, 1.0));
+  o_viewDir  = vec3(o_worldPos - origin);
+  o_texCoord = i_texCoord;
+  o_worldNrm = mat3(pcRaster.modelMatrix) * i_normal;
+
+  gl_Position = uni.viewProj * vec4(o_worldPos, 1.0);
+}

ray_tracing_motionblur/shaders/wavefront.glsl

@@ -0,0 +1,48 @@
+/*
+ * Copyright (c) 2019-2021, NVIDIA CORPORATION.  All rights reserved.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ *
+ * SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
+ * SPDX-License-Identifier: Apache-2.0
+ */
+
+#include "host_device.h"
+
+vec3 computeDiffuse(WaveFrontMaterial mat, vec3 lightDir, vec3 normal)
+{
+  // Lambertian
+  float dotNL = max(dot(normal, lightDir), 0.0);
+  vec3  c     = mat.diffuse * dotNL;
+  if(mat.illum >= 1)
+    c += mat.ambient;
+  return c;
+}
+
+vec3 computeSpecular(WaveFrontMaterial mat, vec3 viewDir, vec3 lightDir, vec3 normal)
+{
+  if(mat.illum < 2)
+    return vec3(0);
+
+  // Compute specular only if not in shadow
+  const float kPi        = 3.14159265;
+  const float kShininess = max(mat.shininess, 4.0);
+
+  // Specular
+  const float kEnergyConservation = (2.0 + kShininess) / (2.0 * kPi);
+  vec3        V                   = normalize(-viewDir);
+  vec3        R                   = reflect(-lightDir, normal);
+  float       specular            = kEnergyConservation * pow(max(dot(V, R), 0.0), kShininess);
+
+  return vec3(mat.specular * specular);
+}