78 lines
2.1 KiB
Text
78 lines
2.1 KiB
Text
#version 460
|
|
#extension GL_EXT_ray_tracing : require
|
|
#extension GL_GOOGLE_include_directive : enable
|
|
#include "raycommon.glsl"
|
|
|
|
layout(binding = 0, set = 0) uniform accelerationStructureEXT topLevelAS;
|
|
layout(binding = 1, set = 0, rgba32f) uniform image2D image;
|
|
|
|
layout(location = 0) rayPayloadEXT hitPayload prd;
|
|
|
|
layout(binding = 0, set = 1) uniform CameraProperties
|
|
{
|
|
mat4 view;
|
|
mat4 proj;
|
|
mat4 viewInverse;
|
|
mat4 projInverse;
|
|
}
|
|
cam;
|
|
|
|
layout(push_constant) uniform Constants
|
|
{
|
|
vec4 clearColor;
|
|
vec3 lightPosition;
|
|
float lightIntensity;
|
|
int lightType;
|
|
int maxDepth;
|
|
}
|
|
pushC;
|
|
|
|
void main()
|
|
{
|
|
const vec2 pixelCenter = vec2(gl_LaunchIDEXT.xy) + vec2(0.5);
|
|
const vec2 inUV = pixelCenter / vec2(gl_LaunchSizeEXT.xy);
|
|
vec2 d = inUV * 2.0 - 1.0;
|
|
|
|
vec4 origin = cam.viewInverse * vec4(0, 0, 0, 1);
|
|
vec4 target = cam.projInverse * vec4(d.x, d.y, 1, 1);
|
|
vec4 direction = cam.viewInverse * vec4(normalize(target.xyz), 0);
|
|
|
|
uint rayFlags = gl_RayFlagsOpaqueEXT;
|
|
float tMin = 0.001;
|
|
float tMax = 10000.0;
|
|
|
|
prd.depth = 0;
|
|
prd.hitValue = vec3(0);
|
|
prd.attenuation = vec3(1.f, 1.f, 1.f);
|
|
prd.done = 1;
|
|
prd.rayOrigin = origin.xyz;
|
|
prd.rayDir = direction.xyz;
|
|
|
|
vec3 hitValue = vec3(0);
|
|
for(;;)
|
|
{
|
|
traceRayEXT(topLevelAS, // acceleration structure
|
|
rayFlags, // rayFlags
|
|
0xFF, // cullMask
|
|
0, // sbtRecordOffset
|
|
0, // sbtRecordStride
|
|
0, // missIndex
|
|
origin.xyz, // ray origin
|
|
tMin, // ray min range
|
|
direction.xyz, // ray direction
|
|
tMax, // ray max range
|
|
0 // payload (location = 0)
|
|
);
|
|
hitValue += prd.hitValue * prd.attenuation;
|
|
|
|
prd.depth++;
|
|
if(prd.done == 1 || prd.depth >= pushC.maxDepth)
|
|
break;
|
|
|
|
origin.xyz = prd.rayOrigin;
|
|
direction.xyz = prd.rayDir;
|
|
prd.done = 1; // Will stop if a reflective material isn't hit
|
|
}
|
|
|
|
imageStore(image, ivec2(gl_LaunchIDEXT.xy), vec4(hitValue, 1.0));
|
|
}
|