191 lines
6.3 KiB
GLSL
191 lines
6.3 KiB
GLSL
/*
|
|
* Copyright (c) 2019-2021, NVIDIA CORPORATION. All rights reserved.
|
|
*
|
|
* Licensed under the Apache License, Version 2.0 (the "License");
|
|
* you may not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS,
|
|
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
* See the License for the specific language governing permissions and
|
|
* limitations under the License.
|
|
*
|
|
* SPDX-FileCopyrightText: Copyright (c) 2019-2021 NVIDIA CORPORATION
|
|
* SPDX-License-Identifier: Apache-2.0
|
|
*/
|
|
|
|
#version 460
|
|
#extension GL_EXT_ray_tracing : require
|
|
#extension GL_EXT_nonuniform_qualifier : enable
|
|
#extension GL_EXT_scalar_block_layout : enable
|
|
#extension GL_GOOGLE_include_directive : enable
|
|
|
|
#include "binding.glsl"
|
|
#include "gltf.glsl"
|
|
#include "raycommon.glsl"
|
|
|
|
hitAttributeEXT vec2 attribs;
|
|
|
|
// clang-format off
|
|
layout(location = 0) rayPayloadInEXT hitPayload prd;
|
|
layout(location = 1) rayPayloadEXT bool isShadowed;
|
|
|
|
layout(set = 0, binding = 0 ) uniform accelerationStructureEXT topLevelAS;
|
|
layout(set = 0, binding = 2) readonly buffer _InstanceInfo {PrimMeshInfo primInfo[];};
|
|
|
|
layout(set = 1, binding = B_VERTICES) readonly buffer _VertexBuf {float vertices[];};
|
|
layout(set = 1, binding = B_INDICES) readonly buffer _Indices {uint indices[];};
|
|
layout(set = 1, binding = B_NORMALS) readonly buffer _NormalBuf {float normals[];};
|
|
layout(set = 1, binding = B_TEXCOORDS) readonly buffer _TexCoordBuf {float texcoord0[];};
|
|
layout(set = 1, binding = B_MATERIALS) readonly buffer _MaterialBuffer {GltfShadeMaterial materials[];};
|
|
layout(set = 1, binding = B_TEXTURES) uniform sampler2D texturesMap[]; // all textures
|
|
|
|
|
|
// clang-format on
|
|
|
|
layout(push_constant) uniform Constants
|
|
{
|
|
vec4 clearColor;
|
|
vec3 lightPosition;
|
|
float lightIntensity;
|
|
int lightType;
|
|
}
|
|
pushC;
|
|
|
|
// Return the vertex position
|
|
vec3 getVertex(uint index)
|
|
{
|
|
vec3 vp;
|
|
vp.x = vertices[3 * index + 0];
|
|
vp.y = vertices[3 * index + 1];
|
|
vp.z = vertices[3 * index + 2];
|
|
return vp;
|
|
}
|
|
|
|
vec3 getNormal(uint index)
|
|
{
|
|
vec3 vp;
|
|
vp.x = normals[3 * index + 0];
|
|
vp.y = normals[3 * index + 1];
|
|
vp.z = normals[3 * index + 2];
|
|
return vp;
|
|
}
|
|
|
|
vec2 getTexCoord(uint index)
|
|
{
|
|
vec2 vp;
|
|
vp.x = texcoord0[2 * index + 0];
|
|
vp.y = texcoord0[2 * index + 1];
|
|
return vp;
|
|
}
|
|
|
|
|
|
void main()
|
|
{
|
|
// Retrieve the Primitive mesh buffer information
|
|
PrimMeshInfo pinfo = primInfo[gl_InstanceCustomIndexEXT];
|
|
|
|
// Getting the 'first index' for this mesh (offset of the mesh + offset of the triangle)
|
|
uint indexOffset = pinfo.indexOffset + (3 * gl_PrimitiveID);
|
|
uint vertexOffset = pinfo.vertexOffset; // Vertex offset as defined in glTF
|
|
uint matIndex = max(0, pinfo.materialIndex); // material of primitive mesh
|
|
|
|
// Getting the 3 indices of the triangle (local)
|
|
ivec3 triangleIndex = ivec3(indices[nonuniformEXT(indexOffset + 0)], //
|
|
indices[nonuniformEXT(indexOffset + 1)], //
|
|
indices[nonuniformEXT(indexOffset + 2)]);
|
|
triangleIndex += ivec3(vertexOffset); // (global)
|
|
|
|
const vec3 barycentrics = vec3(1.0 - attribs.x - attribs.y, attribs.x, attribs.y);
|
|
|
|
// Vertex of the triangle
|
|
const vec3 pos0 = getVertex(triangleIndex.x);
|
|
const vec3 pos1 = getVertex(triangleIndex.y);
|
|
const vec3 pos2 = getVertex(triangleIndex.z);
|
|
const vec3 position = pos0 * barycentrics.x + pos1 * barycentrics.y + pos2 * barycentrics.z;
|
|
const vec3 world_position = vec3(gl_ObjectToWorldEXT * vec4(position, 1.0));
|
|
|
|
// Normal
|
|
const vec3 nrm0 = getNormal(triangleIndex.x);
|
|
const vec3 nrm1 = getNormal(triangleIndex.y);
|
|
const vec3 nrm2 = getNormal(triangleIndex.z);
|
|
vec3 normal = normalize(nrm0 * barycentrics.x + nrm1 * barycentrics.y + nrm2 * barycentrics.z);
|
|
const vec3 world_normal = normalize(vec3(normal * gl_WorldToObjectEXT));
|
|
const vec3 geom_normal = normalize(cross(pos1 - pos0, pos2 - pos0));
|
|
|
|
// TexCoord
|
|
const vec2 uv0 = getTexCoord(triangleIndex.x);
|
|
const vec2 uv1 = getTexCoord(triangleIndex.y);
|
|
const vec2 uv2 = getTexCoord(triangleIndex.z);
|
|
const vec2 texcoord0 = uv0 * barycentrics.x + uv1 * barycentrics.y + uv2 * barycentrics.z;
|
|
|
|
// Vector toward the light
|
|
vec3 L;
|
|
float lightIntensity = pushC.lightIntensity;
|
|
float lightDistance = 100000.0;
|
|
// Point light
|
|
if(pushC.lightType == 0)
|
|
{
|
|
vec3 lDir = pushC.lightPosition - world_position;
|
|
lightDistance = length(lDir);
|
|
lightIntensity = pushC.lightIntensity / (lightDistance * lightDistance);
|
|
L = normalize(lDir);
|
|
}
|
|
else // Directional light
|
|
{
|
|
L = normalize(pushC.lightPosition - vec3(0));
|
|
}
|
|
|
|
// Material of the object
|
|
GltfShadeMaterial mat = materials[nonuniformEXT(matIndex)];
|
|
|
|
// Diffuse
|
|
vec3 diffuse = computeDiffuse(mat, L, world_normal);
|
|
if(mat.pbrBaseColorTexture > -1)
|
|
{
|
|
uint txtId = mat.pbrBaseColorTexture;
|
|
diffuse *= texture(texturesMap[nonuniformEXT(txtId)], texcoord0).xyz;
|
|
}
|
|
|
|
vec3 specular = vec3(0);
|
|
float attenuation = 1;
|
|
|
|
// Tracing shadow ray only if the light is visible from the surface
|
|
if(dot(world_normal, L) > 0)
|
|
{
|
|
float tMin = 0.001;
|
|
float tMax = lightDistance;
|
|
vec3 origin = gl_WorldRayOriginEXT + gl_WorldRayDirectionEXT * gl_HitTEXT;
|
|
vec3 rayDir = L;
|
|
uint flags = gl_RayFlagsTerminateOnFirstHitEXT | gl_RayFlagsOpaqueEXT
|
|
| gl_RayFlagsSkipClosestHitShaderEXT;
|
|
isShadowed = true;
|
|
traceRayEXT(topLevelAS, // acceleration structure
|
|
flags, // rayFlags
|
|
0xFF, // cullMask
|
|
0, // sbtRecordOffset
|
|
0, // sbtRecordStride
|
|
1, // missIndex
|
|
origin, // ray origin
|
|
tMin, // ray min range
|
|
rayDir, // ray direction
|
|
tMax, // ray max range
|
|
1 // payload (location = 1)
|
|
);
|
|
|
|
if(isShadowed)
|
|
{
|
|
attenuation = 0.3;
|
|
}
|
|
else
|
|
{
|
|
// Specular
|
|
specular = computeSpecular(mat, gl_WorldRayDirectionEXT, L, world_normal);
|
|
}
|
|
}
|
|
|
|
prd.hitValue = vec3(lightIntensity * attenuation * (diffuse + specular));
|
|
}
|